path: root/tnslc/compile/compile.tnsl

/##
	Copyright 2021-2022 Kyle Gunger

	This file is licensed under the CDDL 1.0 (the License)
	and may only be used in accordance with the License.
	You should have received a copy of the License with this
	software/source code. If you did not, a copy can be found
	at the following URL:

	https://opensource.org/licenses/CDDL-1.0

	THIS SOFTWARE/SOURCE CODE IS PROVIDED "AS IS" WITH NO
	WARRANTY, GUARANTEE, OR CLAIM OF FITNESS FOR ANY PURPOSE
	EXPRESS OR IMPLIED
#/


;{}{}charp COMMON_ASM = {
	"\tret\n"
}

# Represents a type
;struct VType {
	uint
		_size,
	int
		ptr,
	
	{}charp name
}

# Tracks defined variables in a block
;struct VTrack {
	{}{}charp
		sym_names,
	
	{}VType
		sym_types
}

# Sizes of items
;{}VType type_table = {
	{1, 0, "int8"},
	{2, 0, "int16"},
	{4, 0, "int32"},
	{8, 0, "int64"},
	{8, 0, "int"},
	{1, 0, "uint8"},
	{2, 0, "uint16"},
	{4, 0, "uint32"},
	{8, 0, "uint64"},
	{8, 0, "uint"},
	{4, 0, "float32"},
	{8, 0, "float64"},
	{8, 0, "float"},
	{1, 0, "bool"},
	{8, 0, "void"}
}

# Null type
;VType NT = {0, 0, "null"}

# Returns an index in the vtrack for a given variable name
/; name_to_index ({}charp name, ~VTrack tab) [int]
	/; loop (int i = 0; i < len tab`.sym_names) [i++]
		/; if (string_equate(tab`.sym_names{i}, name))
			;return i
		;/
	;/

	;tnsl.io.print("Failed to find vairable ")
	;tnsl.io.println(name)

	;return -1
;/

# Given an index in the vtrack, returns a string representation of the
# register or memory where that variable is
/; index_to_loc (int index, ~VTrack tab) [{}charp]
	;{}charp out = ""
	;int stack_bytes = 0
	;int reg = 0
	;int i = 0

	/; loop (i < index) [i++]
		/; if (tab`.sym_types{i}._size !> 8 && reg < 7)
			;reg++
		;; else
			;stack_bytes = stack_bytes + tab`.sym_types{i}._size
		;/
	;/
	
	;return out
;/

# Is struct returns true if the type name given is a struct
/; is_struct ({}charp name) [bool]
	/; loop (int i = 0; i < 15) [i++]
		/; if (string_equate(type_table{i}, name))
			;return false
		;/
	;/
	;return true
;/

# Checks if the current token's data is equal to a string
/; token_is(~int cur, ~{}Token data, {}charp str) [bool]
	;return string_equate(data`{cur`}.data`, str)
;/

# Skips in a definition or list until it finds a name
/; skip_to_name (~int cur, ~{}Token data)
	;int tmp = 0
	/; loop (cur` < len data`) [cur`++]
		;tmp = cur` + 1
		/; if (data`{cur`}.token_type == TOKEN_TYPE.DEFWORD && 
				( token_is(~tmp, data, ",") || token_is(~tmp, data, ")") || token_is(~tmp, data, "}") || token_is(~tmp, data, ";") ))
			;break
		;/
	;/
;/

# Searches the type table for a type
/; vtype_by_name ({}charp name) [VType]
	/; loop (int i = 0; i < len type_table) [i++]
		;VType tmp = tnslc.type_table{i}
		/; if (string_equate(name, tmp.name))
			;return tmp
		;/
	;/
	;return NT
;/

# Parses a type in a definition or list
/; get_vtype (~int cur, ~{}Token data) [VType]
	;uint ptr = 0
	;VType out = NT

	/; loop (cur` < len data`) [cur`++]
		;int i = data`{cur`}.token_type
		/; if (token_is(cur, data, "~") || token_is(cur, data, "{"))
			;ptr++
		;; else if (i == TOKEN_TYPE.DEFWORD || i == TOKEN_TYPE.KEYTYPE)
			;out = vtype_by_name(data`{cur`}.data`)
			;break
		;; else if (!token_is(cur, data, "}"))
			;break
		;/
	;/

	;out.ptr = ptr

	;return out
;/

# Assumes cur points to the beginning of the arguments list
# Sets up the VTrack struct that is pointed to.
/; setup_vtrack (~int cur, ~{}Token data, ~VTrack tab)
	;cur`++

	;VType last = NT

	/; loop (cur` < len data`) [cur`++]
		;int pre_skip = cur`
		/; if (token_is(cur, data, ")"))
			;break
		;; else if (!token_is(cur, data, ","))
			;skip_to_name(cur, data)
			/; if (pre_skip == cur`)
				;tab`.sym_types.append(last)
				;tab`.sym_names.append(data`{cur`}.data`)
			;; else
				;last = get_vtype(~pre_skip, data)
				;tab`.sym_types.append(last)
				;tab`.sym_names.append(data`{cur`}.data`)
			;/
		;/
	;/
;/

# 
/; compile_statement (~int cur, ~{}Token data, ~VTrack tab, gsc, ~{}charp hsec, csec, dsec) [bool]
	;cur`++
	/; if (cur` < len data`)
		/; if (token_is(cur, data, "asm"))
			;cur`++
			;{}charp raw_asm = unquote_string(data`{cur`}.data`)
			;raw_asm.append('\n')
			;csec`.append('\t')
			;add_strings(csec, ~raw_asm)
		;; else if (token_is(cur, data, "return"))
			;return true
		;; else if (name_to_index(data`{cur`}.data`, tab) !< 0)
			# set value
			;int i = name_to_index(data`{cur`}.data`, tab)
		;; else if (string_equate(data`{cur`+1}.data`, "("))
			# Function call
			;eval(cur, data, tab, gsc, hsec, csec, dsec, "ax")
		;; else
			#Definition
			;VType def_t = get_vtype(cur, data)
			;cur`++
			
			/; loop (data`{cur`}.token_type == TOKEN_TYPE.DEFWORD)
				;tab`.sym_types.append(def_t)
				;tab`.sym_names.append(data`{cur`}.data`)
				;cur`++
				/; if (token_is(cur, data, ","))
					;cur`++
				;; else if (token_is(cur, data "="))
					;{}charp loc = index_to_loc(len tab`.sym_names - 1, tab)
					;eval(cur, data, tab, gsc, hsec, csec, dsec, loc)
					/; if (token_is(cur, data, ","))
						;cur`++
					;/
				;/
			;/
			/; if (string_equate(data`{cur`+1}.data`, "="))

			;/
		;/
	;/

	;return false
;/

/; compile_block (~int cur, ~{}Token data, ~VTrack gsc, ~{}charp hsec, csec, dsec)
	;VTrack tab = { {}, {} }
	;VType out_type = NT
	;{}charp name = ""
	;bool r = false

	/; loop (cur`++; cur` < len data`) [cur`++]
		/; if (data`{cur`}.token_type == TOKEN_TYPE.DEFWORD && len name == 0)
			;name = data`{cur`}.data`
			;add_strings(csec, ~name)
			;csec`.append(':')
			;csec`.append('\n')
		;; else if (token_is(cur, data, "("))
			;setup_vtrack(cur, data, ~tab)
		;; else if (token_is(cur, data, "["))
			;cur`++
			;out_type = get_vtype(cur, data)
			;cur`++
		;; else if (token_is(cur, data, "raw"))
			;r = true
		;; else
			;break
		;/
	;/

	;tnsl.io.println(out_type.name)

	/; if (!r)
		;header_guard(csec)
	;/

	;bool ret = false
	/; loop (cur` < len data` && !ret) [cur`++]
		/; if (string_equate(data`{cur`}.data`, ";/"))
			/; if (!r)
				;tail_guard(csec)
			;/
			;add_strings(csec, ~(tnslc.COMMON_ASM{0}))
			;break
		;; else if (string_equate(data`{cur`}.data`, "/;"))
			;bool ch = true
			/; loop (ch)
				;compile_block(cur, data, hsec, csec, dsec)
				/; if (cur` !< len data`)
					;break
				;/
				;ch = string_equate(data`{cur`}.data`, ";;")
			;/			
		;; else if (string_equate(data`{cur`}.data`, ";"))
			;ret = compile_statement(cur, data, ~tab, gsc, hsec, csec, dsec)
			/; if (ret)
				/; if (!r)
					;tail_guard(csec)
				;/
				;add_strings(csec, ~(tnslc.COMMON_ASM{0}))
			;/
		;; else
			;tnsl.io.print("Failed to compile token [compile_block]: ")
			;data`{cur`}.print()
			;tnsl.io.println("")
			;break
		;/
	;/

	;csec`.append('\n')
;/

/; do_compile ({}charp file, ~{}Token data)
	;{}charp hsec = ".global main\n"
	;{}charp csec = ".text\n"
	;{}charp dsec = ".data\n"

	;int j = len data`
	
	;VTrack global_scope = {{}, {}}

	/; loop (int i = 0; i < j) [i++]
		/; if (string_equate(data`{i}.data`, "/;"))
			;compile_block(~i, data, ~hsec, ~csec, ~dsec)
		;; else if (string_equate(data`{i}.data`, ";"))
			;compile_global(~i, data, ~hsec, ~csec, ~dsec)
		;; else
			;break
		;/
	;/

	;tnsl.io.File out = tnsl.io.writeFile(file)
	
	/; loop (int i = 0; i < len hsec) [i++]
		;out.write(hsec{i})
	;/

	;out.write('\n')

	/; loop (int i = 0; i < len csec) [i++]
		;out.write(csec{i})
	;/

	;out.write('\n')

	/; loop (int i = 0; i < len dsec) [i++]
		;out.write(dsec{i})
	;/

	;out.write('\n')
	;out.close()
;/